Sensores MEMS: acelerómetro, giroscopio, magnetómetro

#include 

const int MPU_ADDR = 0x68;    // Dirección I2C del MPU-6050
int16_t accelX, accelY, accelZ; // Variables para acelerómetro
int16_t gyroX, gyroY, gyroZ;    // Variables para giroscopio
float temperatura;

void setup() {
  Serial.begin(115200);
  Wire.begin();
  
  // Despertar el MPU-6050 (por defecto está en modo sleep)
  Wire.beginTransmission(MPU_ADDR);
  Wire.write(0x6B);  // Registro de administración de energía
  Wire.write(0);     // Poner en 0 para despertar
  Wire.endTransmission(true);
  
  Serial.println("MPU-6050 inicializado");
}

void loop() {
  // Leer acelerómetro
  Wire.beginTransmission(MPU_ADDR);
  Wire.write(0x3B);  // Registro inicial del acelerómetro
  Wire.endTransmission(false);
  Wire.requestFrom(MPU_ADDR, 6, true);  // Solicitar 6 bytes
  
  accelX = Wire.read() << 8 | Wire.read();  // 0x3B y 0x3C
  accelY = Wire.read() << 8 | Wire.read();  // 0x3D y 0x3E
  accelZ = Wire.read() << 8 | Wire.read();  // 0x3F y 0x40
  
  // Leer temperatura
  Wire.beginTransmission(MPU_ADDR);
  Wire.write(0x41);  // Registro de temperatura
  Wire.endTransmission(false);
  Wire.requestFrom(MPU_ADDR, 2, true);
  
  int16_t temp_raw = Wire.read() << 8 | Wire.read();
  temperatura = temp_raw / 340.0 + 36.53;  // Fórmula del datasheet
  
  // Leer giroscopio
  Wire.beginTransmission(MPU_ADDR);
  Wire.write(0x43);  // Registro inicial del giroscopio
  Wire.endTransmission(false);
  Wire.requestFrom(MPU_ADDR, 6, true);
  
  gyroX = Wire.read() << 8 | Wire.read();
  gyroY = Wire.read() << 8 | Wire.read();
  gyroZ = Wire.read() << 8 | Wire.read();
  
  // Mostrar resultados
  Serial.println("=== DATOS MPU-6050 ===");
  Serial.printf("Acelerómetro: X=%d, Y=%d, Z=%d\n", accelX, accelY, accelZ);
  Serial.printf("Giroscopio: X=%d, Y=%d, Z=%d\n", gyroX, gyroY, gyroZ);
  Serial.printf("Temperatura: %.2f°C\n", temperatura);
  Serial.println();
  
  delay(1000);
}

// Factores de escala (dependen de la configuración del sensor)
float accel_scale = 16384.0;  // Para ±2g
float gyro_scale = 131.0;     // Para ±250°/s

void mostrarDatosCalibrasdos() {
  // Convertir a unidades físicas
  float ax = accelX / accel_scale;  // g (gravedad)
  float ay = accelY / accel_scale;
  float az = accelZ / accel_scale;
  
  float gx = gyroX / gyro_scale;    // °/s
  float gy = gyroY / gyro_scale;
  float gz = gyroZ / gyro_scale;
  
  // Cálculos de ángulos (aproximados)
  float roll = atan2(ay, az) * 180 / PI;
  float pitch = atan2(-ax, sqrt(ay*ay + az*az)) * 180 / PI;
  
  Serial.println("=== DATOS CALIBRADOS ===");
  Serial.printf("Aceleración: X=%.2fg, Y=%.2fg, Z=%.2fg\n", ax, ay, az);
  Serial.printf("Velocidad angular: X=%.2f°/s, Y=%.2f°/s, Z=%.2f°/s\n", gx, gy, gz);
  Serial.printf("Ángulos: Roll=%.1f°, Pitch=%.1f°\n", roll, pitch);
}